home *** CD-ROM | disk | FTP | other *** search
/ Turnbull China Bikeride / Turnbull China Bikeride - Disc 2.iso / STUTTGART / LANG / ADA / GNAT / !gcc / adainc / 4 / adb / s-imgbiu < prev    next >
Text File  |  1996-02-12  |  6KB  |  159 lines
  1. ------------------------------------------------------------------------------
  2. --                                                                          --
  3. --                         GNAT RUNTIME COMPONENTS                          --
  4. --                                                                          --
  5. --                       S Y S T E M . I M G _ B I U                        --
  6. --                                                                          --
  7. --                                 B o d y                                  --
  8. --                                                                          --
  9. --                            $Revision: 1.6 $                              --
  10. --                                                                          --
  11. --     Copyright (C) 1992,1993,1994,1995 Free Software Foundation, Inc.     --
  12. --                                                                          --
  13. -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  14. -- terms of the  GNU General Public License as published  by the Free Soft- --
  15. -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  16. -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  17. -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  18. -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  19. -- for  more details.  You should have  received  a copy of the GNU General --
  20. -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  21. -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  22. -- MA 02111-1307, USA.                                                      --
  23. --                                                                          --
  24. -- As a special exception,  if other files  instantiate  generics from this --
  25. -- unit, or you link  this unit with other files  to produce an executable, --
  26. -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  27. -- covered  by the  GNU  General  Public  License.  This exception does not --
  28. -- however invalidate  any other reasons why  the executable file  might be --
  29. -- covered by the  GNU Public License.                                      --
  30. --                                                                          --
  31. -- GNAT was originally developed  by the GNAT team at  New York University. --
  32. -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  33. --                                                                          --
  34. ------------------------------------------------------------------------------
  35.  
  36. with System.Unsigned_Types; use System.Unsigned_Types;
  37.  
  38. package body System.Img_BIU is
  39.  
  40.    -----------------------------
  41.    -- Set_Image_Based_Integer --
  42.    -----------------------------
  43.  
  44.    procedure Set_Image_Based_Integer
  45.      (V : Integer;
  46.       B : Natural;
  47.       W : Integer;
  48.       S : out String;
  49.       P : in out Natural)
  50.    is
  51.       Start : Natural;
  52.  
  53.    begin
  54.       --  Positive case can just use the unsigned circuit directly
  55.  
  56.       if V >= 0 then
  57.          Set_Image_Based_Unsigned (Unsigned (V), B, W, S, P);
  58.  
  59.       --  Negative case has to set a minus sign. Note also that we have to be
  60.       --  careful not to generate overflow with the largest negative number.
  61.  
  62.       else
  63.          P := P + 1;
  64.          S (P) := ' ';
  65.          Start := P;
  66.  
  67.          declare
  68.             pragma Suppress (Overflow_Check);
  69.             pragma Suppress (Range_Check);
  70.          begin
  71.             Set_Image_Based_Unsigned (Unsigned (-V), B, W - 1, S, P);
  72.          end;
  73.  
  74.          --  Set minus sign in last leading blank location. Because of the
  75.          --  code above, there must be at least one such location.
  76.  
  77.          while S (Start + 1) = ' ' loop
  78.             Start := Start + 1;
  79.          end loop;
  80.  
  81.          S (Start) := '-';
  82.       end if;
  83.  
  84.    end Set_Image_Based_Integer;
  85.  
  86.    ------------------------------
  87.    -- Set_Image_Based_Unsigned --
  88.    ------------------------------
  89.  
  90.    procedure Set_Image_Based_Unsigned
  91.      (V : Unsigned;
  92.       B : Natural;
  93.       W : Integer;
  94.       S : out String;
  95.       P : in out Natural)
  96.    is
  97.       Start : constant Natural := P;
  98.       F, T  : Natural;
  99.       BU    : constant Unsigned := Unsigned (B);
  100.       Hex   : constant array
  101.                 (Unsigned range 0 .. 15) of Character := "0123456789ABCDEF";
  102.  
  103.       procedure Set_Digits (T : Unsigned);
  104.       --  Set digits of absolute value of T
  105.  
  106.       procedure Set_Digits (T : Unsigned) is
  107.       begin
  108.          if T >= BU then
  109.             Set_Digits (T / BU);
  110.             P := P + 1;
  111.             S (P) := Hex (T mod BU);
  112.          else
  113.             P := P + 1;
  114.             S (P) := Hex (T);
  115.          end if;
  116.       end Set_Digits;
  117.  
  118.    --  Start of processing for Set_Image_Based_Unsigned
  119.  
  120.    begin
  121.  
  122.       if B >= 10 then
  123.          P := P + 1;
  124.          S (P) := '1';
  125.       end if;
  126.  
  127.       P := P + 1;
  128.       S (P) := Character'Val (Character'Pos ('0') + B mod 10);
  129.  
  130.       P := P + 1;
  131.       S (P) := '#';
  132.  
  133.       Set_Digits (V);
  134.  
  135.       P := P + 1;
  136.       S (P) := '#';
  137.  
  138.       --  Add leading spaces if required by width parameter
  139.  
  140.       if P - Start < W then
  141.          F := P;
  142.          P := Start + W;
  143.          T := P;
  144.  
  145.          while F > Start loop
  146.             S (T) := S (F);
  147.             T := T - 1;
  148.             F := F - 1;
  149.          end loop;
  150.  
  151.          for J in Start + 1 .. T loop
  152.             S (J) := ' ';
  153.          end loop;
  154.       end if;
  155.  
  156.    end Set_Image_Based_Unsigned;
  157.  
  158. end System.Img_BIU;
  159.